Caps Lock 키는 주요 키보드 공간을 차지하며 무게를 당기지 않습니다. 이 쉬운 AutoHotkey 스크립트는 Caps Lock을 수정자 키로 바꾸어 사용자 정의 가능한 단축키에 사용할 수 있습니다.

기초

이 스크립트를 사용하면 Windows 어디에서나 Caps Lock+G를 눌러 빠르게 Google 텍스트를 검색하거나 Caps Lock+D를 눌러 단어의 사전 정의를 조회할 수 있습니다. 물론 이러한 단축키는 사용자 정의할 수 있습니다.

무엇보다도 이 영리한 스크립트를 사용하면 Caps Lock을 정상적으로 사용할 수 있습니다. Caps Lock을 빠르게 두 번 눌러 켜거나 끌 수 있습니다. 그렇지 않으면 Caps Lock이 바로 가기의 수정 키로 작동합니다.

오토핫키 101

AutoHotkey는 백그라운드에서 스크립트를 실행하는 무료 Windows 응용 프로그램입니다. 이러한 스크립트는 직접 작성하거나 다운로드할 수 있습니다. 스크립트는 일반적으로 키를 누르고 작업을 수행합니다. 이런 식으로 AutoHotkey는 Windows에서 키를 다시 매핑하거나 키에 다른 작업을 할당하는 빠른 방법입니다.

예를 들어, AutoHotkey를 사용하여 Windows 키를 비활성화하여 시작 메뉴를 열지 못하게 하고 전체 화면 PC 게임을 종료하는 방법을 보여주었습니다. 키보드에서 키 캡을 들어 올릴 필요가 없습니다.

AutoHotkey 설치 및 스크립트 가져오기

오토핫키 다운로드 시작하려면 설치하십시오. 다음으로 CapsLock Modifier 스크립트를 다운로드합니다.

ZIP 아카이브 파일에서 AHK 스크립트 파일을 추출하여 컴퓨터의 아무 폴더에나 넣습니다. AutoHotkey로 실행하려면 스크립트를 마우스 오른쪽 버튼으로 클릭하고 “스크립트 실행”을 선택하십시오.

이제 스크립트가 백그라운드에서 실행 중입니다. Caps Lock을 켜고 끄려면 Caps Lock 키를 빠르게 두 번 탭합니다.

두 번 탭하지 않으면 Caps Lock이 보조 키로 작동합니다. 스크립트에 내장된 기능을 사용하여 Windows의 모든 위치에서 다음 바로 가기를 사용할 수 있습니다.

Caps Lock + d를 눌러 선택한 단어의 사전 정의를 찾습니다.
Caps Lock + g를 눌러 Windows에서 선택한 텍스트를 Google에서 검색합니다.
Caps Lock + t를 눌러 동의어 사전에서 선택한 단어를 찾습니다.
Caps Lock + w를 눌러 Wikipedia에서 선택한 텍스트를 검색합니다.

더 많은 단축키를 원하십니까? AutoHotkey 스크립트에 대한 약간의 지식으로 자신만의 스크립트를 만들 수 있습니다.

AutoHotkey를 제어하려면 알림 영역에서 AutoHotkey 아이콘을 찾으십시오. 녹색 배경에 흰색 H가 있습니다. 스크립트 실행을 중지하려면 AutoHotkey 아이콘을 마우스 오른쪽 버튼으로 클릭하고 “종료”를 선택하십시오.

어떻게 작동합니까?

스크립트가 무엇을 하는지 보려면 스크립트를 마우스 오른쪽 버튼으로 클릭하고 대신 “스크립트 편집”을 선택하십시오. 이렇게 하면 메모장에서 스크립트가 열리고 해당 코드를 검사할 수 있습니다. 스크립트가 상당히 짧고 이해하기 쉽습니다. 이상한 스크립트를 먼저 보고 이해하지 않고 다운로드하여 실행하지 않는 것이 좋습니다.

이 스크립트는 Dave Kellog가 우리에게 보냈습니다. 다음은 Caps Lock을 두 번 누르면 수정 키로 작동하도록 하는 스크립트의 마법 부분입니다.

CapsLock::
KeyWait, CapsLock ; Wait forever until Capslock is released.
KeyWait, CapsLock, D T0.2 ; ErrorLevel = 1 if CapsLock not down within 0.2 seconds.
if ((ErrorLevel = 0) && (A_PriorKey = "CapsLock") ) ; Is a double tap on CapsLock?
{
SetCapsLockState, % GetKeyState("CapsLock","T") ? "Off" : "On" ; Toggle the state of CapsLock LED
}
return

이 비트는 Caps Lock이 두 번 눌러졌는지 확인하고 Caps Lock을 켜거나 끕니다. 그렇지 않으면 스크립트가 Caps Lock을 캡처하여 수정자 바로 가기에 사용합니다.

스크립트의 나머지 부분에는 바로 가기 작업과 클립보드의 내용을 저장하고 복원하는 유용한 클립보드 기능이 포함되어 있습니다. 수정자 함수가 클립보드를 사용하여 선택한 텍스트에 대한 작업을 수행하기 때문에 이 부분은 매우 필요합니다.

전체 스크립트를 다운로드하지 않고 보고 싶으십니까? 여기있어:

#NoEnv                      ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn                     ; Enable warnings to assist with detecting common errors.
#SingleInstance FORCE       ; Skip invocation dialog box and silently replace previously executing instance of this script.
SendMode Input              ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.


;================================================================================================
;  CapsLock processing.  Must double tap CapsLock to toggle CapsLock mode on or off.
;================================================================================================
; Must double tap CapsLock to toggle CapsLock mode on or off.
CapsLock::
    KeyWait, CapsLock                                                   ; Wait forever until Capslock is released.
    KeyWait, CapsLock, D T0.2                                           ; ErrorLevel = 1 if CapsLock not down within 0.2 seconds.
    if ((ErrorLevel = 0) && (A_PriorKey = "CapsLock") )                 ; Is a double tap on CapsLock?
        {
        SetCapsLockState, % GetKeyState("CapsLock","T") ? "Off" : "On"  ; Toggle the state of CapsLock LED
        }
return



;================================================================================================
; Hot keys with CapsLock modifier.  See https://autohotkey.com/docs/Hotkeys.htm#combo
;================================================================================================
; Get DEFINITION of selected word.    
CapsLock & d::
    ClipboardGet()
    Run, http://www.google.com/search?q=define+%clipboard%     ; Launch with contents of clipboard
    ClipboardRestore()
Return

; GOOGLE the selected text.
CapsLock & g::
    ClipboardGet()
    Run, http://www.google.com/search?q=%clipboard%             ; Launch with contents of clipboard
    ClipboardRestore()
Return

; Do THESAURUS of selected word
CapsLock & t::
    ClipboardGet()
    Run http://www.thesaurus.com/browse/%Clipboard%             ; Launch with contents of clipboard
    ClipboardRestore()
Return

; Do WIKIPEDIA of selected word
CapsLock & w::
    ClipboardGet()
    Run, https://en.wikipedia.org/wiki/%clipboard%              ; Launch with contents of clipboard
    ClipboardRestore()
Return

;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++

;================================================================================================
; Clipboard helper functions.
;================================================================================================
ClipboardGet()
{
    OldClipboard:= ClipboardAll                         ;Save existing clipboard.
    Clipboard:= ""
    Send, ^c                                            ;Copy selected test to clipboard
    ClipWait 0
    If ErrorLevel
        {
        MsgBox, No Text Selected!
        Return
        }
}


ClipboardRestore()
{
    Clipboard:= OldClipboard
}

이전에 Caps Lock을 수정 키로 바꾸는 AutoHotkey 스크립트를 본 적이 있지만 두 번 누를 때 Caps Lock을 토글로 유지하는 스크립트는 본 적이 없습니다. 아주 똑똑합니다. 보내주신 Dave Kello님께 다시 한번 감사드립니다.